Ce programme calcule la largeur partielle du W Boson en Electron + Electron antineutrino.
Réalisé sur Citrix Mathematica 5.2 au CENBG.  Exige accès au Directory indiqué, qui est dans la zone "échanges" du CENBG.

SetDirectory["I:\\Donohue_HIP\\launcher3"]

On charge les programmes .m  nécessaires à HIP.

<< NonCommutativeMultiply.m

\(\(\(	\)\(<< RelativisticKinematics.m\)\)\)

<< Spinor.m

<< Class.m

<< StandardModel.m

<< CrossSection.m

<< SpinorTechniques.m

On désigne l'indice mu qui sera utilisée, et on spécifie les masses et impulsions (quadri-vecteurs) des participants.

PrepareIndex[mu]
SetMass[{pe, Mass[Electron]}, {pν, Mass[ElectronNeutrino]}, {pw, Mass[WBoson]}]

L'élément de matrice est spécifiée pour  \(TraditionalForm\`\(W\^-\)\)->e + \(TraditionalForm\`ν\&_\).  Attention à la notation ** pour Diracologie!

ME = SpinorUbar[pe] ** 
	Vertex[Electron, ElectronNeutrino, {WBoson, pw, mu}] ** SpinorV[pν]

On calcule le carré de l'élément de matrice, et on contracte avec un vecteur unitaire de polarisation dans le direction Z (3)

MEsqdpolZ1=Factor[Contract[G[3,mu]*G[3,Conjugate[mu]]*AbsSquared[ME], {mu, Conjugate[mu]}]]

On informe HIP de la valeur numériqe de G[3,3], on evalue le produit scalaire, et on utilise le fait que dans le référentiel du W Boson, les impulsions de l'électron et du neutrino sont égales et opposées.

MEsqdpolZ2 = 
      ReplaceAll[
        MEsqdpolZ1, {G[3, 3] -> -1, 
          DotProduct[pe, 
              pν] -> (Mass[WBoson]^2 - Mass[Electron]^2)/2, 
          pe[3] -> -pν[3]}]

On indique à HIP la valeur de la composante 3 de l'impulsion du neutrino, en introduisant l'angle θ entre pν et l'axe Z.

MEsqdpolZ3 = 
      ReplaceAll[MEsqdpolZ2, 
        pν[3] -> 
          Cos[θ]*(Mass[WBoson] - (Mass[Electron]^2)/
                    Mass[WBoson])/2]

On introduit le facteur trouvé dans le livre de Quigg, p.309.

QuiggFacteur = (Mass[WBoson]^2 - 
            Mass[Electron]^2)/(64*(π^2)*
            Mass[WBoson]^3)

On intégre sur l'angle solide Sin[θ]dθdϕ.

LargeurW = 
      QuiggFacteur*
        Integrate[
          Integrate[MEsqdpolZ3*Sin[θ], {θ, 0, π}], {ϕ, 
            0, 2*π}]

On demande à HIP la valeur numerique. C'est un peu datée.

N[Evaluate[LargeurW]]

On peut aussi utiliser la méthode de sommation sur les états de polarization du W-Boson, avec l'option HeavyVectorPolarization[p,indice]

MEbis = 
      SpinorUbar[pe] ** Vertex[Electron, ElectronNeutrino, {WBoson, pw, mu}] ** 
          SpinorV[pν]*HeavyVectorPolarization[pw, mu]

On calcule le carré de l'élément de matrice, et on divise par le nombre d'états de polarisation, 3. La somme sur les 3 polarisations est implicite dans cette approche.

MEbissqd1 = 
      Factor[Contract[AbsSquared[MEbis], {mu, Conjugate[mu]}]]/3

On introduit la cinématique.  Il n'y a plus de dépendance en θ, ni en ϕ.

MEbissqd2 = 
      ReplaceAll[
        MEbissqd1, {DotProduct[pe, 
              pw] -> (Mass[WBoson]^2 + Mass[Electron]^2)/2,  
          DotProduct[pw, pν] -> (Mass[WBoson]^2 - Mass[Electron]^2)/
              2, DotProduct[pe, 
              pν]  -> (Mass[WBoson]^2 - Mass[Electron]^2)/
              2}]

On vérifie que le même résultat est obtenu.

N[4*π*QuiggFacteur*MEbissqd2]

Pour être complet,  
    on va calculer avec le vecteur de polarisation ((Overscript[x, ∧]) + 
            i  (Overscript[y, ∧]))/(Sqrt[2]),  ce qui correspond au (Subscript[J, z])  = 1,  
    pour le W.

MEsqdPolXIY=(1/2)*Factor[Contract[G[1,mu]*G[1,Conjugate[mu]]*AbsSquared[ME], {mu, Conjugate[mu]}]+Contract[G[2,mu]*G[2,Conjugate[mu]]*AbsSquared[ME], {mu, Conjugate[mu]}]-I*Contract[G[1,mu]*G[2,Conjugate[mu]]*AbsSquared[ME], {mu, Conjugate[mu]}]+I*Contract[G[2,mu]*G[1,Conjugate[mu]]*AbsSquared[ME], {mu, Conjugate[mu]}]]

\(Cinématique, \ θ\ pour\ le\ ν\&_, \ 
    attention\ \ ϵ\_0123 = 1. \)

reponse1=FullSimplify[ReplaceAll[MEsqdPolXIY,{G[1,1]->-1,G[2,2]->-1,DotProduct[pe,pν]->(Mass[WBoson]^2-Mass[Electron]^2)/2,Eps[1,2,pe,pν]->Cos[θ]*(Mass[WBoson]^2-Mass[Electron]^2)/2,pe[1] pν[1]->-pe[2] pν[2]-(1-Cos[θ]^2)*(Mass[WBoson]^2-Mass[Electron]^2)/4}]]

\(La\ distribution\ angulaire . \ \ le\ ν\&_\ est\ émis\ plutôt\ vers\ θ\  = 0. \ \(\(Pourquoi\)\(?\)\)\)

ParametricPlot[{Cos[θ], Cos[(θ/2)]^4}, {θ, 
        0, π}]

La largeur est toujours

N[QuiggFacteur*
        Integrate[
          Integrate[reponse1*Sin[θ], {θ, 0, π}], {ϕ, 
            0, 2*π}]]